Everything in a Place: How to convert a numeric value into English words in Excel 2003, 2007, 2010, 2013, 2016 in Taka

Wednesday, March 14, 2018

How to convert a numeric value into English words in Excel 2003, 2007, 2010, 2013, 2016 in Taka

How to convert a numeric value into English words in Excel 2003, 2007, 2010, 2013, 2016 in Bangladeshi Taka

Applies to: Microsoft Office Excel 2003Microsoft Office Excel 2007 Microsoft Excel 2010 Excel 2016 Excel 2013

Summary

This article contains sample Microsoft Visual Basic for Applications functions that you can use to convert a numeric value in a Microsoft Excel worksheet cell into its equivalent in English words.

More Information

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure. However, they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements.

How to create the sample function Called SpellNumberTaka

Start Microsoft Excel.
Press ALT+F11 to start the Visual Basic Editor.
On the Insert menu, click Module.
Type the following code into the module sheet.

Option Explicit
'Main Function
Function SpellNumberTaka(ByVal MyNumber)
    Dim Taka, Paisa, Temp
    Dim DecimalPlace, Count
    ReDim Place(9) As String
    Place(2) = " Thousand "
    Place(3) = " Million "
    Place(4) = " Billion "
    Place(5) = " Trillion "
    ' String representation of amount.
    MyNumber = Trim(Str(MyNumber))
    ' Position of decimal place 0 if none.
    DecimalPlace = InStr(MyNumber, ".")
    ' Convert Paisa and set MyNumber to taka amount.
    If DecimalPlace > 0 Then
        Paisa = GetTens(Left(Mid(MyNumber, DecimalPlace + 1) & _
                  "00", 2))
        MyNumber = Trim(Left(MyNumber, DecimalPlace - 1))
    End If
    Count = 1
    Do While MyNumber <> ""
        Temp = GetHundreds(Right(MyNumber, 3))
        If Temp <> "" Then Taka = Temp & Place(Count) & Taka
        If Len(MyNumber) > 3 Then
            MyNumber = Left(MyNumber, Len(MyNumber) - 3)
        Else
            MyNumber = ""
        End If
        Count = Count + 1
    Loop
    Select Case Taka
        Case ""
            Taka = "No Taka"
        Case "One"
            Taka = "One Taka"
         Case Else
            Taka = Taka & " Taka"
    End Select
    Select Case Paisa
        Case ""
            Paisa = " and No Paisa Only"
        Case "One"
            Paisa = " and One Paisa Only"
              Case Else
            Paisa = " and " & Paisa & " Paisa Only"
    End Select
    SpellNumberTaka = Taka & Paisa
End Function

' Converts a number from 100-999 into text
Function GetHundreds(ByVal MyNumber)
    Dim Result As String
    If Val(MyNumber) = 0 Then Exit Function
    MyNumber = Right("000" & MyNumber, 3)
    ' Convert the hundreds place.
    If Mid(MyNumber, 1, 1) <> "0" Then
        Result = GetDigit(Mid(MyNumber, 1, 1)) & " Hundred "
    End If
    ' Convert the tens and ones place.
    If Mid(MyNumber, 2, 1) <> "0" Then
        Result = Result & GetTens(Mid(MyNumber, 2))
    Else
        Result = Result & GetDigit(Mid(MyNumber, 3))
    End If
    GetHundreds = Result
End Function

' Converts a number from 10 to 99 into text.
Function GetTens(TensText)
    Dim Result As String
    Result = ""           ' Null out the temporary function value.
    If Val(Left(TensText, 1)) = 1 Then   ' If value between 10-19...
        Select Case Val(TensText)
            Case 10: Result = "Ten"
            Case 11: Result = "Eleven"
            Case 12: Result = "Twelve"
            Case 13: Result = "Thirteen"
            Case 14: Result = "Fourteen"
            Case 15: Result = "Fifteen"
            Case 16: Result = "Sixteen"
            Case 17: Result = "Seventeen"
            Case 18: Result = "Eighteen"
            Case 19: Result = "Nineteen"
            Case Else
        End Select
    Else                                 ' If value between 20-99...
        Select Case Val(Left(TensText, 1))
            Case 2: Result = "Twenty "
            Case 3: Result = "Thirty "
            Case 4: Result = "Forty "
            Case 5: Result = "Fifty "
            Case 6: Result = "Sixty "
            Case 7: Result = "Seventy "
            Case 8: Result = "Eighty "
            Case 9: Result = "Ninety "
            Case Else
        End Select
        Result = Result & GetDigit _
            (Right(TensText, 1)) ' Retrieve ones place.
    End If
    GetTens = Result
End Function

' Converts a number from 1 to 9 into text.
Function GetDigit(Digit)
    Select Case Val(Digit)
        Case 1: GetDigit = "One"
        Case 2: GetDigit = "Two"
        Case 3: GetDigit = "Three"
        Case 4: GetDigit = "Four"
        Case 5: GetDigit = "Five"
        Case 6: GetDigit = "Six"
        Case 7: GetDigit = "Seven"
        Case 8: GetDigit = "Eight"
        Case 9: GetDigit = "Nine"
        Case Else: GetDigit = ""
    End Select
End Function

How to use the SpellNumberTaka sample function

To use the sample functions to change a number to written text, use one of the methods demonstrated in the following examples:

Method 1: Direct Entry

You can change 32.50 into "Thirty Two Taka and Fifty Paisa Only" by entering the following formula into a cell:

=SpellNumberTaka(32.50)

Method 2: Cell reference

You can refer to other cells in the workbook. For example, enter the number 32.50 into cell A1, and type the following formula into another cell:

=SpellNumberTaka(A1)

Method 3: Insert Function

To use Insert Function, follow these steps:

Excel 2003:

Select the cell that you want.
Click Insert Function on the Standard toolbar.
Under Or select a category, click User Defined.
In the Select a function list, click SpellNumber, and then click OK.
Enter the number or cell reference that you want, and then click OK.

Excel 2007 and 2010:

Select the cell that you want.
Click Insert Function on the Formulas ribbon.
Under Or select a category, click User Defined.
In the Select a function list, click SpellNumberTaka, and then click OK.
Enter the number or cell reference that you want, and then click OK.